init

.zprezto/modules/archive/README.md

@@ -0,0 +1,40 @@
+Archive
+=======
+
+Provides functions to list and extract archives.
+
+Functions
+---------
+
+  - `lsarchive` lists the contents of one or more archives.
+  - `unarchive` extracts the contents of one or more archives.
+
+Supported Formats
+-----------------
+
+The following archive formats are supported when the required utilities are
+installed:
+
+  - *.tar.gz*, *.tgz* require `tar`.
+  - *.tar.bz2*, *.tbz* require `tar`.
+  - *.tar.xz*, *.txz* require `tar` with *xz* support.
+  - *.tar.zma*, *.tlz* require `tar` with *lzma* support.
+  - *.tar* requires `tar`.
+  - *.gz* requires `gunzip`.
+  - *.bz2* requires `bunzip2`.
+  - *.xz* requires `unxz`.
+  - *.lzma* requires `unlzma`.
+  - *.Z* requires `uncompress`.
+  - *.zip* requires `unzip`.
+  - *.rar* requires `unrar` or `rar`.
+  - *.7z* requires `7za`.
+  - *.deb* requires `ar`, `tar`.
+
+Authors
+-------
+
+*The authors of this module should be contacted via the [issue tracker][1].*
+
+  - [Sorin Ionescu](https://github.com/sorin-ionescu)
+
+[1]: https://github.com/sorin-ionescu/prezto/issues

.zprezto/modules/archive/functions/_lsarchive

@@ -0,0 +1,13 @@
+#compdef lsarchive
+#autoload
+
+#
+# Completes lsarchive.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+_arguments \
+  '(-v --verbose)'{-v,--remove}'[verbose archive listing]' \
+  "*::archive file:_files -g '(#i)*.(tar|tgz|tbz|tbz2|txz|tlz|gz|bz2|xz|lzma|Z|zip|rar|7z)(-.)'" && return 0

.zprezto/modules/archive/functions/_unarchive

@@ -0,0 +1,13 @@
+#compdef unarchive
+#autoload
+
+#
+# Completes unarchive.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+_arguments \
+  '(-r --remove)'{-r,--remove}'[remove archive]' \
+  "*::archive file:_files -g '(#i)*.(tar|tgz|tbz|tbz2|txz|tlz|gz|bz2|xz|lzma|Z|zip|rar|7z|deb)(-.)'" && return 0

.zprezto/modules/archive/functions/lsarchive

@@ -0,0 +1,55 @@
+#
+# Lists the contents of archives.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+local verbose
+
+if (( $# == 0 )); then
+  cat >&2 <<EOF
+usage: $0 [-option] [file ...]
+
+options:
+    -v, --verbose    verbose archive listing
+
+Report bugs to <sorin.ionescu@gmail.com>.
+EOF
+fi
+
+if [[ "$1" == "-v" || "$1" == "--verbose" ]]; then
+  verbose=0
+  shift
+fi
+
+while (( $# > 0 )); do
+  if [[ ! -s "$1" ]]; then
+    print "$0: file not valid: $1" >&2
+    shift
+    continue
+  fi
+
+  case "$1:l" in
+    (*.tar.gz|*.tgz) tar t${verbose:+v}vzf "$1" ;;
+    (*.tar.bz2|*.tbz|*.tbz2) tar t${verbose:+v}jf "$1" ;;
+    (*.tar.xz|*.txz) tar --xz --help &> /dev/null \
+      && tar --xz -t${verbose:+v}f "$1" \
+      || xzcat "$1" | tar t${verbose:+v}f - ;;
+    (*.tar.zma|*.tlz) tar --lzma --help &> /dev/null \
+      && tar --lzma -t${verbose:+v}f "$1" \
+      || lzcat "$1" | tar x${verbose:+v}f - ;;
+    (*.tar) tar t${verbose:+v}f "$1" ;;
+    (*.zip) unzip -l${verbose:+v} "$1" ;;
+    (*.rar) unrar &> /dev/null \
+      && unrar ${${verbose:+v}:-l} "$1" \
+      || rar ${${verbose:+v}:-l} "$1" ;;
+    (*.7z) 7za l "$1" ;;
+    (*)
+      print "$0: cannot list: $1" >&2
+      success=1
+    ;;
+  esac
+
+  shift
+done

.zprezto/modules/archive/functions/unarchive

@@ -0,0 +1,80 @@
+#
+# Extracts the contents of archives.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+local remove_archive
+local success
+local file_name
+local file_path
+local extract_dir
+
+if (( $# == 0 )); then
+  cat >&2 <<EOF
+usage: $0 [-option] [file ...]
+
+options:
+    -r, --remove    remove archive
+
+Report bugs to <sorin.ionescu@gmail.com>.
+EOF
+fi
+
+remove_archive=1
+if [[ "$1" == "-r" || "$1" == "--remove" ]]; then
+  remove_archive=0
+  shift
+fi
+
+while (( $# > 0 )); do
+  if [[ ! -s "$1" ]]; then
+    print "$0: file not valid: $1" >&2
+    shift
+    continue
+  fi
+
+  success=0
+  file_name="${1:t}"
+  file_path="${1:A}"
+  extract_dir="${file_name:r}"
+  case "$1:l" in
+    (*.tar.gz|*.tgz) tar xvzf "$1" ;;
+    (*.tar.bz2|*.tbz|*.tbz2) tar xvjf "$1" ;;
+    (*.tar.xz|*.txz) tar --xz --help &> /dev/null \
+      && tar --xz -xvf "$1" \
+      || xzcat "$1" | tar xvf - ;;
+    (*.tar.zma|*.tlz) tar --lzma --help &> /dev/null \
+      && tar --lzma -xvf "$1" \
+      || lzcat "$1" | tar xvf - ;;
+    (*.tar) tar xvf "$1" ;;
+    (*.gz) gunzip "$1" ;;
+    (*.bz2) bunzip2 "$1" ;;
+    (*.xz) unxz "$1" ;;
+    (*.lzma) unlzma "$1" ;;
+    (*.Z) uncompress "$1" ;;
+    (*.zip) unzip "$1" -d $extract_dir ;;
+    (*.rar) unrar &> /dev/null \
+      && unrar x -ad "$1" \
+      || rar x -ad "$1" ;;
+    (*.7z) 7za x "$1" ;;
+    (*.deb)
+      mkdir -p "$extract_dir/control"
+      mkdir -p "$extract_dir/data"
+      cd "$extract_dir"; ar vx "${file_path}" > /dev/null
+      cd control; tar xvf ../control.tar.*
+      cd ../data; tar xvf ../data.tar.*
+      cd ..; rm control.tar.* data.tar.* debian-binary
+      cd ..
+    ;;
+    (*)
+      print "$0: cannot extract: $1" >&2
+      success=1
+    ;;
+  esac
+
+  (( success = $success > 0 ? $success : $? ))
+  (( $success == 0 )) && (( $remove_archive == 0 )) && rm "$1"
+  shift
+done