init

.zprezto/modules/ruby/README.md

@@ -0,0 +1,108 @@
+Ruby
+====
+
+Configures [Ruby][1] local gem installation, loads version managers, and defines
+aliases.
+
+Local Gem Installation
+----------------------
+
+When a Ruby version manager is not detected, local gems are installed in
+*~/.gems*; otherwise, they are installed according to the manager.
+
+RVM
+---
+
+An alternative to the above is to use [The Ruby Version Manager (RVM)][2], which
+allows for managing multiple, isolated Ruby installations and gem sets in the
+home directory.
+
+Since RVM is loaded into the shell and is known to override shell commands, it
+may conflict with shell scripts.
+
+Load this module as late as possible when using RVM since RVM will complain if
+it is not first in `$PATH`.
+
+rbenv
+-----
+
+An alternative RVM is to use [rbenv][3], which allows for switching between
+multiple, isolated Ruby installations in the home directory.
+
+While it is not as feature rich as RVM, it is not loaded into the shell and is
+not known to cause conflicts with shell scripts.
+
+chruby
+------
+
+Yet another alternative is [chruby][6], which is simpler than both RVM and
+rbenv.
+
+### Settings
+
+#### Auto-Switch
+
+To enable auto switching the Ruby version on directory change based on the
+.ruby-version file, add the following line to *zpreztorc*:
+
+    zstyle ':prezto:module:ruby:chruby' auto-switch 'yes'
+
+Bundler
+-------
+
+Manage gems that are not meant to be used as commands, such as application
+dependencies, with [Bundler][4].
+
+Aliases
+-------
+
+### General
+
+  - `rb` is short for `ruby`.
+
+### Bundler
+
+  - `rbb` manages ruby dependencies (`bundle`).
+  - `rbbe` executes a script in the context of the current bundle.
+  - `rbbi` installs the gems specified in the *Gemfile* in *vendor/bundle*.
+  - `rbbI` installs the following:
+    - gems specified in the *Gemfile* in *vendor/bundle*.
+    - packages the gems into *vendor/cache*.
+    - appends bundler directories to  *.gitignore*.
+  - `rbbl` lists all gems in the current bundle.
+  - `rbbo` opens an installed gem in the editor.
+  - `rbbp` packages gem files into *vendor/cache*.
+  - `rbbu` updates gems to their latest version.
+
+Functions
+---------
+
+  - `ruby-app-root` displays the path to the Ruby application root directory.
+  - `ruby-info` exposes information about the Ruby environment via the
+    `$ruby_info` associative array.
+
+Theming
+-------
+
+To display the name of the current Ruby version in a prompt, define the
+following style in the `prompt_name_setup` function.
+
+    # %v - ruby version.
+    zstyle ':prezto:module:ruby:info:version' format 'version:%v'
+
+Then add `$ruby_info[version]` to `$PROMPT` or `$RPROMPT` and call
+`ruby-info` in the `prompt_name_preexec` hook function.
+
+Authors
+-------
+
+*The authors of this module should be contacted via the [issue tracker][5].*
+
+  - [Sorin Ionescu](https://github.com/sorin-ionescu)
+
+[1]: http://www.ruby-lang.org
+[2]: https://rvm.io
+[3]: https://github.com/sstephenson/rbenv
+[4]: http://gembundler.com
+[5]: https://github.com/sorin-ionescu/prezto/issues
+[6]: https://github.com/postmodern/chruby

.zprezto/modules/ruby/functions/ruby-app-root

@@ -0,0 +1,18 @@
+#
+# Displays the path to the Ruby application root directory.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+local root_dir="$PWD"
+
+while [[ "$root_dir" != '/' ]]; do
+  if [[ -f "$root_dir/Gemfile" ]]; then
+    print "$root_dir"
+    break
+  fi
+  root_dir="$root_dir:h"
+done
+
+return 1

.zprezto/modules/ruby/functions/ruby-info

@@ -0,0 +1,30 @@
+#
+# Exposes information about the Ruby environment via the $ruby_info associative
+# array.
+#
+# Authors:
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+local version
+local version_format
+local version_formatted
+
+# Clean up previous $ruby_info.
+unset ruby_info
+typeset -gA ruby_info
+
+if (( $+commands[rvm-prompt] )); then
+  version="$(rvm-prompt)"
+elif (( $+commands[rbenv] )); then
+  version="$(rbenv version-name)"
+elif (( $+commands[ruby] )); then
+  version="${${$(ruby --version)[(w)1,(w)2]}/ /-}"
+fi
+
+# Format version.
+if [[ -n "$version" ]]; then
+  zstyle -s ':prezto:module:ruby:info:version' format 'version_format'
+  zformat -f version_formatted "$version_format" "v:$version"
+  ruby_info[version]="$version_formatted"
+fi

.zprezto/modules/ruby/init.zsh

@@ -0,0 +1,68 @@
+#
+# Configures Ruby local gem installation, loads version managers, and defines
+# aliases.
+#
+# Authors: Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+
+# Load RVM into the shell session.
+if [[ -s "$HOME/.rvm/scripts/rvm" ]]; then
+  # Unset AUTO_NAME_DIRS since auto adding variable-stored paths to ~ list
+  # conflicts with RVM.
+  unsetopt AUTO_NAME_DIRS
+
+  # Source RVM.
+  source "$HOME/.rvm/scripts/rvm"
+
+# Load manually installed rbenv into the shell session.
+elif [[ -s "$HOME/.rbenv/bin/rbenv" ]]; then
+  path=("$HOME/.rbenv/bin" $path)
+  eval "$(rbenv init - --no-rehash zsh)"
+
+# Load package manager installed rbenv into the shell session.
+elif (( $+commands[rbenv] )); then
+  eval "$(rbenv init - --no-rehash zsh)"
+
+# Load package manager installed chruby into the shell session.
+elif (( $+commands[chruby-exec] )); then
+  source "${commands[chruby-exec]:h:h}/share/chruby/chruby.sh"
+  if zstyle -t ':prezto:module:ruby:chruby' auto-switch; then
+    source "${commands[chruby-exec]:h:h}/share/chruby/auto.sh"
+
+    # If a default Ruby is set, switch to it.
+    chruby_auto
+  fi
+
+# Prepend local gems bin directories to PATH.
+else
+  path=($HOME/.gem/ruby/*/bin(N) $path)
+fi
+
+# Return if requirements are not found.
+if (( ! $+commands[ruby] && ! ( $+commands[rvm] || $+commands[rbenv] ) )); then
+  return 1
+fi
+
+#
+# Aliases
+#
+
+# General
+alias rb='ruby'
+
+# Bundler
+if (( $+commands[bundle] )); then
+  alias rbb='bundle'
+  alias rbbe='bundle exec'
+  alias rbbi='bundle install --path vendor/bundle'
+  alias rbbl='bundle list'
+  alias rbbo='bundle open'
+  alias rbbp='bundle package'
+  alias rbbu='bundle update'
+  alias rbbI='rbbi \
+    && bundle package \
+    && print .bundle       >>! .gitignore \
+    && print vendor/assets >>! .gitignore \
+    && print vendor/bundle >>! .gitignore \
+    && print vendor/cache  >>! .gitignore'
+fi